home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The 640 MEG Shareware Studio 2
/
The 640 Meg Shareware Studio CD-ROM Volume II (Data Express)(1993).ISO
/
mailers
/
binkla20.zip
/
BKLACONN.BAS
< prev
next >
Wrap
BASIC Source File
|
1992-02-19
|
5KB
|
133 lines
DEFINT A-Z
DECLARE FUNCTION FUsing$ (Num$, Image$) 'PDQ use
' Program: BKLAConn
' Author: RJ (Bob) Ross - FidoNet 1:134/75
' Date Started: January 28th, 1992
' Date Finished: February 2nd, 1992
' Purpose: To tabulate the percentage of outgoing call
' connects.
'
' Note: BinkLA must be run with the -D switch to create
' BKLARpt.Dat file. BKLARpt.Txt must be available
' to extract the report heading information.
'
' BKLAConn was compiled using QuickBASIC 4.5 and linked
' using Crescent's PDQ library to reduce the exe size.
' The program may be linked with QuickBASIC's Link program.
' See the remarks in the program where modification is
' required for this.
' BKLARpt.Dat Variable declaractions
'-----------------------------------
DIM ZoneNetNode AS STRING * 15
DIM CallsOut AS INTEGER
DIM Connect AS INTEGER
DIM CallsIn AS INTEGER
DIM MByteOut AS LONG
DIM MByteIn AS LONG
DIM MTimeOut AS INTEGER
DIM MTimeIn AS INTEGER
DIM MByteOutIn AS LONG
DIM MTimeOutIn AS LONG
DIM MAvgCPS AS INTEGER
DIM MTimeMinute AS SINGLE
DIM RptHeading$(1 TO 6)
ON ERROR GOTO Drats 'global error trap
OPEN "BKLARpt.Txt" FOR INPUT AS #1 'for report heading
OPEN "BKLARpt.Dat" FOR INPUT AS #2 'Input file
OPEN "BKLAConn.Txt" FOR OUTPUT AS #3 'Output file
FOR X% = 1 TO 6
LINE INPUT #1, RptHeading$(X%)
PRINT #3, RptHeading$(X%)
NEXT
CLOSE (1)
'Column Headings
'---------------
PRINT #3, SPACE$(9); "┌"; STRING$(57, "─"); "┐"
PRINT #3, SPACE$(9); "│ ▓▓▓▓▓▓▓▓▓▓ Percentage of Outgoing Connects ▓▓▓▓▓▓▓▓▓▓ │"
PRINT #3, SPACE$(9); "╞"; STRING$(57, "═"); "╡"
PRINT #3, SPACE$(9); "│ Node │ Calls Out │ Connect";
PRINT #3, " │ Connect % │"
PRINT #3, SPACE$(9); "├"; STRING$(57, "─"); "┤"
DO UNTIL EOF(2)
'Get data from BKLARpt.Dat
'-------------------------
INPUT #2, ZoneNetNode, CallsOut, Connect, CallsIn
INPUT #2, MByteOut, MByteIn, MTimeOut, MTimeIn
INPUT #2, MByteOutIn, MTimeOutIn, MAvgCPS, MTimeMinute
TotCallsOut& = TotCallsOut& + CallsOut
TotConnect& = TotConnect& + (Connect - CallsIn)
OutPerCent! = 0
IF CallsOut > 0 AND Connect > 0 THEN
OutPerCent! = (Connect - CallsIn) / CallsOut * 100
END IF
'Output detail lines to BKLAConn.Txt
'-----------------------------------
IF CallsOut = 0 THEN
'Do Nothing
ELSE
'QuickBasic or QBasic Specific Code
'----------------------------------
' PRINT #3, SPACE$(9); "│ "; ZoneNetNode; SPACE$(7);
' PRINT #3, USING "####"; CallsOut;
' PRINT #3, SPACE$(8);
' PRINT #3, USING "####"; Connect - CallsIn;
' PRINT #3, SPACE$(10);
' PRINT #3, USING "###.#"; OutPerCent!;
' PRINT #3, TAB(68); "│"
'PDQ Specific Code
'-----------------
CallsOutPDQ$ = FUsing$(STR$(CallsOut), "####")
ConnInPDQ$ = FUsing$(STR$(Connect - CallsIn), "####")
OutPerCentPDQ$ = FUsing$(STR$(OutPerCent!), "###.#")
PRINT #3, SPACE$(9); "│ "; ZoneNetNode; SPACE$(7);
PRINT #3, CallsOutPDQ$; SPACE$(8); ConnInPDQ$; SPACE$(10);
PRINT #3, OutPerCentPDQ$; TAB(68); "│"
END IF
LOOP
'Summarize
'---------
'QuickBasic or QBasic specific code
'----------------------------------
' PRINT #3, SPACE$(9); "├"; STRING$(57, "─"); "┤"
' PRINT #3, SPACE$(9); "│ TOTAL"; SPACE$(14);
' PRINT #3, USING "#####"; TotCallsOut&;
' PRINT #3, SPACE$(7);
' PRINT #3, USING "#####"; TotConnect&;
' PRINT #3, SPACE$(10);
' PRINT #3, USING "###.#"; (TotConnect& / TotCallsOut&) * 100;
' PRINT #3, TAB(68); "│"
' PRINT #3, SPACE$(9); "╘"; STRING$(57, "═"); "╛"
'PDQ specific code
'-----------------
TotCallsOutPDQ$ = FUsing$(STR$(TotCallsOut&), "#####")
TotConnectPDQ$ = FUsing$(STR$(TotConnect&), "#####")
TotCPerCentPDQ$ = FUsing$(STR$((TotConnect& / TotCallsOut&) * 100), "###.#")
PRINT #3, SPACE$(9); "├"; STRING$(57, "─"); "┤"
PRINT #3, SPACE$(9); "│ TOTAL"; SPACE$(14);
PRINT #3, TotCallsOutPDQ$; SPACE$(7); TotConnectPDQ$; SPACE$(10);
PRINT #3, TotCPerCentPDQ$;
PRINT #3, TAB(68); "│"
PRINT #3, SPACE$(9); "╘"; STRING$(57, "═"); "╛"
CLOSE
PRINT "BKLAConn.Txt - Done"
SYSTEM
Drats:
BEEP: PRINT "Program Failed!"
CLOSE : SYSTEM